This is not only an advanced problem, but also one still very open to critisism. There are currently no CO2 controls native in the program to open and close windows or for scheduling equipment on/off. There is a CO2 DCV setup and examples in the example file.
For your problem, I suggest using EMS to manipulate the fan availibilty schedule to on or off depending on monitored CO2. As for window operation with AFN...this is an advanced topic.
Attatched is a excertp of a report pending review, where I have implemented a system to mimick human window operation.
Window Opening logic are as follows:
a) Windows/Doors only operate during occupation hours.
b) x1 zone small window opens for a minimum of 1 minute period. It will close again if the room air temperature falls below setpoint. It will only open if the room air is above setpoint. It will open if the zone air becomes too warm at zone heating setpoint + 3 deg C or if the CO2 level reaches 2000 ppm. CO2 levels in ppm were modeled to check that they are in bounds of health and safety regulations�peak CO2 levels aare seen to reach approximately 4000 ppm in winter, with a winter daily average of 2200 ppm in the worst case zone. This is in-line with the 90% statistical mean (2724 ppm) and statistical maximum (4172 ppm) for schools in Germany [ref. H. Fromme, et.al, Gesundheitswesen 2008, "Air quality in schools - classroom levels of carbon dioxide (CO2), volatile organic compounds (VOC), aldehydes, endotoxins and cat allergen"].
c) Although, the window may close again after 1 minute, the re-evaluation of whether or not to open a window is restricted
artificially to 120 minutes. This limit was imposed for three reasons:
1) to keep the unmet load hours to below 300 as per ASHRAE 90.1, as no radiant floor system will meet the
load of an open window in winter.
2) to keep results within line with current research publications on the matter [ref. OCCUPANT INTERACTION
WITH VENTILATION SYSTEMS 7th AIC Conference, Stratford-upon-Avon, UK 29 September - 2 October
1986] and [ref. WINDOW OPENING BEHAVIOUR IN A NATURALLY VENTILATED SCHOOL, SIMBuild
Aug. 13 2010] which suggest x5 per day as an appropriate number and
3) because it is thought that too frequent opening in winter will result in children catching a cold due to the large temperature swings associated with opening the windows.
d) If the outdoor temperature goes over 19 deg C, the large operable window (if any) will also open, as will the operable roof windows and will stay open until the temperature drops below the zone heating setpoint, else it will close after 1 minutes and re-evaluate after 2 hours.
e) There is no night ventilation, as there is no night occupation.
f) Other peripheral occupied zone doors remain shut if other windows are available for venting.
g) Windows will close if there is too much draft in the room, i.e. average ACH exceeds 15 over a 60 minute interval.
h) An overheating scenario is anticipated also at cold outdoor air temperatures in winter, due to intense solar infall into the zone (because of the low solar angle, zone temps rise above 28ºC). The restrictions of ASHRAE 90.1 prohibit (according to the LEED EAp2 reviewer) the modeling in both baseline and designcase models of:
a. Manual blind operation, which would in reality negate this problem.
b. Turning lighting off is also not allowed, because these systems are not automated.
c. Lastly, the surrounding trees and buildings are also not allowed to be modeled (according to the LEED EAp2 reviewer).
12.3.4 The Window Ventilation Control Algorithm
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!WINDOW VENTING CONTROL!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!An alternative to the stoastic approach as per Occupant Behaviour with regard to Control of Indoor Environment,
!PhD Thesis, Rune Vinther Andersen,
!International Centre for Indoor Environment and Energy,
!Department of Civil Engineering, Technical University of Denmark, 2009
!
ZoneAirContaminantBalance,Yes, !- Carbon Dioxide Concentration
ODACO2Sch; !- Outdoor Carbon Dioxide Schedule Name
!
Schedule:Compact,
ODACO2Sch,
Any Number,
Through: 12/31,
For: AllDays,
Until: 24:00, 450; !City = 700, Ave=450, Nature=350
!the 90% Statistical Maximum for German Schools should be around 450 (summer and winter)
!H. Fromme, et.al, Gesundheitswesen 2008, "Air quality in schools - classroom levels of carbon dioxide (CO2), volatile organic compounds (VOC), aldehydes, endotoxins and cat allergen"
!
Schedule:Compact,
InHiCO2Sch,
Any Number,
Through: 12/31,
For: AllDays,
Until: 24:00, 2000; !corrolates to 35% dissatisfied (include for 1hr realization delay from 1100 ppm)
!the 90% Statistical Maximum for German Schools should be around 2700
!H. Fromme, et.al, Gesundheitswesen 2008, "Air quality in schools - classroom levels of carbon dioxide (CO2), volatile organic compounds (VOC), aldehydes, endotoxins and cat allergen"
!
Schedule:Compact,
InLowCO2Sch,
Any Number,
Through: 12/31,
For: AllDays,
Until: 24:00, 500; !corrolates to 3.3% dissatisfied...PD = 395*exp(-15.15*(Cout-Cin)^(-0.25)) ...European Concerted Action Report No. 11. Guidelines for. Ventilation Requirements in Buildings, 1992, fig. 3
!
!ODA CO2 sensor
EnergyManagementSystem:Sensor,
ODACO2, ! Sensor Name...reporting schedule properties
ODACO2Sch, ! Output:Variable or Output:Meter Index Key Name Zone/Sys Thermostat Cooling Setpoint Output:Variable,*,Zone/Sys Thermostat Cooling Setpoint,hourly; !- Zone Average [C]
Schedule Value; ! Output:Variable or Output:Meter Name
!
!ODA dry-bulb temperature sensor
EnergyManagementSystem:Sensor,
ODATemp, ! Sensor Name...reporting schedule properties
Environment, ! Output:Variable or Output:Meter Index Key Name Zone/Sys Thermostat Cooling Setpoint Output:Variable,*,Zone/Sys Thermostat Cooling Setpoint,hourly; !- Zone Average [C]
Site Outdoor Air Drybulb Temperature; ! Output:Variable or Output:Meter Name
!
!Global Zone allowable CO2 Hi
EnergyManagementSystem:Sensor,
CO2_Hi, ! Sensor Name...reporting temperature
InHiCO2Sch,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Schedule Value; ! Output:Variable or Output:Meter Name
!
!Global Zones allowable CO2 Low
EnergyManagementSystem:Sensor,
CO2_Low, ! Sensor Name...reporting temperature
InLowCO2Sch,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Schedule Value; ! Output:Variable or Output:Meter Name
!
Output:EnergyManagementSystem,
Verbose,
Verbose,
ErrorsOnly ;
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!EMS for Occupant Zone Window Control by CO2 Level and Temperature
!*****THIS FILE IS USED TO GENERATE A FILE THAT HAS THAT NEED TO BE REMOVED******!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!Default Large Window Schedule
Schedule:Compact,
118129_VENT, !- Name
Any Number, !- Schedule Type Limits Name
Through: 12/31, !- Field 1
For: AllDays, !- Field 2
Until: 24:00,0; !- Field 3
!Default Small Window Schedule...the main actuator
Schedule:Compact,
118129_VENT2, !- Name
Any Number, !- Schedule Type Limits Name
Through: 12/31, !- Field 1
For: AllDays, !- Field 2
Until: 24:00,0; !- Field 3
!Default external door Schedule...applied to zones that only have the external door to ventilate
!Because the opening area is larger, the minimum ventilation time is reduced from 5-10 min to 2 min.
! this 3rd opening set together with its sensor/Actuator is not used, but retained for future use
Schedule:Compact,
118129_VENT3,
Any Number, !- Schedule Type Limits Name
Through: 12/31, !- Field 1
For: AllDays, !- Field 2 !- Field 2
Until: 24:00,0; !- Field 3
! this schedule together with its sensor is not used, but retained for future use
Schedule:Compact,
TinLowSch_118129,
Any Number,
Through: 12/31,
For: AllDays,
Until: 24:00, 17.5; !17.5 KLASSE II - Kindergarten nach CEN 15251-2007
!this schedule together with its sensor is not used, but retained for future use
Schedule:Compact,
TinHiSch_118129,
Any Number,
Through: 12/31,
For: AllDays,
Until: 24:00, 23.5; !23.5 KLASSE II - Kindergarten nach CEN 15251-2007
!
Output:Variable,118129,Zone Air CO2 Concentration,hourly ;
Output:Variable,118129_VENT,Schedule Value,hourly; !- Zone Average []
Output:Variable,118129_VENT2,Schedule Value,hourly; !- Zone Average []
Output:Variable,118129,People Occupant Count,hourly; !- Zone Average []
!
EnergyManagementSystem:GlobalVariable,
WinPos_118129, !- Erl Variable 2 Name
Win2Pos_118129, !- Erl Variable 2 Name
Win3Pos_118129, !- Erl Variable 2 Name
ACHv_118129, !- Erl Variable 2 Name
WORv_118129 ;
!
!Window position at previous timestep
EnergyManagementSystem:TrendVariable,
preWinPos_118129, !- Name
WinPos_118129, !- EMS Variable Name to be tracked
120; !- Number of Timesteps to be Logged
!
!Window 2 position at previous timestep
EnergyManagementSystem:TrendVariable,
preWin2Pos_118129, !- Name
Win2Pos_118129, !- EMS Variable Name to be tracked
120; !- Number of Timesteps to be Logged
!
!Window 3 position at previous timestep
EnergyManagementSystem:TrendVariable,
preWin3Pos_118129, !- Name
Win3Pos_118129, !- EMS Variable Name to be tracked
120; !- Number of Timesteps to be Logged
!
!Zone ACH trend values
EnergyManagementSystem:TrendVariable,
TrdACH_118129, !- Name
ACHv_118129, !- EMS Variable Name to be tracked
120; !- Number of Timesteps to be Logged
!
!Zone ACH trend values
EnergyManagementSystem:TrendVariable,
WORTrend_118129, !- Name
WORv_118129, !- EMS Variable Name to be tracked
120; !- Number of Timesteps to be Logged
!
!Global Zones allowable Indoor Low Temp
EnergyManagementSystem:Sensor,
T_Low_118129, ! Sensor Name...reporting temperature
TinLowSch_118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Schedule Value; ! Output:Variable or Output:Meter Name
!
!Global Zones allowable Indoor Low Temp
EnergyManagementSystem:Sensor,
T_Hi_118129, ! Sensor Name...reporting temperature
TinHiSch_118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Schedule Value; ! Output:Variable or Output:Meter Name
!
!Zone CO2 sensor
EnergyManagementSystem:Sensor,
CO2_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Zone Air CO2 Concentration; ! Output:Variable or Output:Meter Name
!
!Zone Temp sensor
EnergyManagementSystem:Sensor,
T_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Zone Mean Air Temperature; ! Output:Variable or Output:Meter Name
!
!Zone Radiant Temp sensor
EnergyManagementSystem:Sensor,
TR_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Zone Mean Radiant Temperature; ! Output:Variable or Output:Meter Name
!
!Zone occupation sensor
EnergyManagementSystem:Sensor,
Occ_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Zone People Occupant Count; ! Output:Variable or Output:Meter Name
!
!Zone htgSP
EnergyManagementSystem:Sensor,
htgSP_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
Zone Thermostat Heating Setpoint Temperature; ! Output:Variable or Output:Meter Name
!
EnergyManagementSystem:Sensor,
ACH_118129, ! Sensor Name...reporting temperature
118129,! Output:Variable or Output:Meter Index Key Name Output:Variable,*,Outdoor Dry Bulb,hourly; !- Zone Average [C]
AFN Zone Infiltration Air Change Rate; ! Output:Variable or Output:Meter Name
!
EnergyManagementSystem:Actuator,
A_118129, !- Name
118129_VENT, !- Actuated Component Unique Name...in this case !-EnergyManagementSystem:Actuator Available,COOLING SP SCH,Schedule:Compact,Schedule Value,[ ]
Schedule:Compact, !- Actuated Component Type
Schedule Value ; !- Actuated Component Control Type
!
EnergyManagementSystem:Actuator,
A2_118129, !- Name
118129_VENT2, !- Actuated Component Unique Name...in this case !-EnergyManagementSystem:Actuator Available,COOLING SP SCH,Schedule:Compact,Schedule Value,[ ]
Schedule:Compact, !- Actuated Component Type
Schedule Value ; !- Actuated Component Control Type
!
EnergyManagementSystem:Actuator,
A3_118129, !- Name
118129_VENT3, !- Actuated Component Unique Name...in this case !-EnergyManagementSystem:Actuator Available,COOLING SP SCH,Schedule:Compact,Schedule Value,[ ]
Schedule:Compact, !- Actuated Component Type
Schedule Value ; !- Actuated Component Control Type
!
!***Program Calling Proceedure***
EnergyManagementSystem:ProgramCallingManager,
WinPrgCallMngr_118129, ! Name
AfterPredictorAfterHVACManagers, ! EnergyPlus Model Calling Point
WinPrg_118129; ! Program 1 Name
!
!***Main Program***
!******************
EnergyManagementSystem:Program,
WinPrg_118129, ! Program 1 Name
!
SET ACHv_118129 = ACH_118129,
!
!Manipulation of windows only when zone is occupied and zone heating setpoint has been achieved
IF (Occ_118129 > 0),
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!WINDOW SMALL
!close if too cold air
IF ((@TrendSum preWin2Pos_118129 1) == 1),
IF (T_118129 >= htgSP_118129),
SET A2_118129 = 1,
SET Win2Pos_118129 = 1,
ELSE,
SET A2_118129 = Null,
SET Win2Pos_118129 = 0,
ENDIF,
ENDIF,
!open if it was closed for the last 2 hrs and is too hot
IF ((@TrendSum preWin2Pos_118129 120) == 0),
IF (((T_118129 + TR_118129)/2) >= (htgSP_118129 + 3)),
SET A2_118129 = 1,
SET Win2Pos_118129 = 1,
ELSE,
SET A2_118129 = Null,
SET Win2Pos_118129 = 0,
ENDIF,
ENDIF,
!open if it was closed for the last 2 hrs and is too stinky, but room is at setpoint
IF ((@TrendSum preWin2Pos_118129 120) == 0),
IF (T_118129 >= htgSP_118129),
IF (CO2_118129 >= CO2_Hi),
SET A2_118129 = 1,
SET Win2Pos_118129 = 1,
ENDIF,
ENDIF,
ENDIF,
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!EXTERNAL DOOR
!close if too cold air
IF ((@TrendSum preWin3Pos_118129 1) == 1),
IF (T_118129 >= htgSP_118129),
SET A3_118129 = 1,
SET Win3Pos_118129 = 1,
ELSE,
SET A3_118129 = Null,
SET Win3Pos_118129 = 0,
ENDIF,
ENDIF,
!open if it was closed for the last 2 hrs and is too hot
IF ((@TrendSum preWin3Pos_118129 120) == 0),
IF (((T_118129 + TR_118129)/2) >= (htgSP_118129 + 3)),
SET A3_118129 = 1,
SET Win3Pos_118129 = 1,
ELSE,
SET A3_118129 = Null,
SET Win3Pos_118129 = 0,
ENDIF,
ENDIF,
!open if it was closed for the last 2 hrs and is too stinky, but room is at setpoint
IF ((@TrendSum preWin3Pos_118129 120) == 0),
IF (T_118129 >= htgSP_118129),
IF (CO2_118129 >= CO2_Hi),
SET A3_118129 = 1,
SET Win3Pos_118129 = 1,
ENDIF,
ENDIF,
ENDIF,
!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!WINDOW LARGE
!oda is greater than 19 deg C...........................................
IF (ODATemp >= 19),
IF ((@TrendSum preWinPos_118129 120) == 0),
IF (((T_118129 + TR_118129)/2) >= (htgSP_118129 + 3) ),
SET A_118129 = 1,
SET WinPos_118129 = 1,
ELSE,
SET A_118129 = Null,
SET WinPos_118129 = 0,
ENDIF,
ENDIF,
ENDIF,
!
IF (ODATemp >= 19),
IF ((@TrendSum preWinPos_118129 1) == 1),
IF (T_118129 >= htgSP_118129),
SET A_118129 = 1,
SET WinPos_118129 = 1,
ELSE,
SET A_118129 = Null,
SET WinPos_118129 = 0,
ENDIF,
ENDIF,
ENDIF,
!
!60 min wind/draft override override!!!approx. over 15 ACH over any 60 minute interval!!!
IF ((@TrendAverage TrdACH_118129 60) > 15),
SET SET WORv_118129 = 1,
IF ((@TrendSum WORTrend_118129 60) == 60),
SET A2_118129 = Null,
SET Win2Pos_118129 = 0,
SET A_118129 = Null,
SET WinPos_118129 = 0,
SET WORv_118129 = 0,
ENDIF,
ENDIF,
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
ELSEIF (Occ_118129 == 0),
SET A_118129 = 0,
SET A2_118129 = 0,
ENDIF;!Manipulation of windows only when zone is occupied and zone heating setpoint has been achieved
!
!***End Main Program***
!**********************
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
Hi!
I've the same problem! there's someone who can help us?
--- In EnergyPlus_Support@xxxxxxxxxxxxxxx, <energyplus_support@xxxxxxxxxxxxxxx> wrote:May anyone help me with this topic?
Thanks in advance,
Juliana.
--- In EnergyPlus_Support@xxxxxxxxxxxxxxx, "jhidalgo131" <julianahidalgo@...> wrote:
>
> Hi everyone!
>
> I ask for help with the following situation: I need to simulate a ventilation system for an hotel room. It includes natural ventilation through windows, a CO2 detector and an exhaust fan that will operate when the detector indicates that there is a high level of CO2 inside the room. I've been trying to define this at Natural Ventilation and Duct Leakage field but I'm not sure how can I define on the program the working schedule for the exhaust fan, since it will depend on the CO2 detection.
> One more question: Is it correct to simulate the system I described with the object Network Airflow? or is there another way to do it?
>
> I would appreciate a lot any advice.
>
> Best regards,
>
> Juliana.
>